BackOver

Минимальные требования к среде разработки:

• actionScript 2.0 и FlashPlayer не ниже 8.0;
• actionScript 3.0 и FlashPlayer не ниже 9.0.

Что необходимо подготовить:

• flash-ролик (*.swf), не более 300 КБ;
• картинку-заглушку (*.jpg, *.png, *.gif);
• фоновое изображение (*.jpg, *.png, *.gif).

Подготовка Flash-ролика на ActionScript 2.0:

1. Создайте верхний слой, назовите его adfoxTransitionButton, и разместите в нем прозрачную кнопку, которой присвойте имя transitionButton.

   При клике на кнопку будет произведен переход на сайт рекламодателя, при наведении курсора мыши на кнопку покажется фоновое изображение, при отведении курсора — фон сайта принимает первоначальный вид.

2. Скопируйте код и вставьте его в код на кнопке:

   on (rollOver) 
   { 
       if(flash.external.ExternalInterface.available)
       {
           loadMovieNum(_root.event_1, 300);
           flash.external.ExternalInterface.call('ADFOX.BACKOVER.globals.applyBackground' + _root.adfoxBannerId);
       }
   } 
   
   on (rollOut) 
   { 
       if(flash.external.ExternalInterface.available)
       {
           flash.external.ExternalInterface.call('ADFOX.BACKOVER.globals.resetBackground' + _root.adfoxBannerId);
       }
   }
   
   on (release) 
   { 
       if(flash.external.ExternalInterface.available)
       {
           //IE driven hack;
           flash.external.ExternalInterface.call('ADFOX.BACKOVER.globals.resetBackground' + _root.adfoxBannerId);
           flash.external.ExternalInterface.call('window.open', _root.link1, _root.adfoxTarget);
       }
       else
       {
           getURL(_root.link1, _root.adfoxTarget);
       }
   } 

Подготовка Flash-ролика на ActionScript 3.0:

1. Создайте верхний слой, назовите его adfoxTransitionButton, и разместите в нем прозрачную кнопку, которой присвойте имя transitionButton.

   При клике на кнопку будет произведен переход на сайт рекламодателя, при наведении курсора мыши на кнопку покажется фоновое изображение, при отведении курсора — фон сайта принимает первоначальный вид.

2. Скопируйте код и вставьте его в первый кадр главного таймлайн:

   import flash.events.Event;
   import flash.external.ExternalInterface;
   import flash.net.navigateToURL;
   import flash.net.URLRequest;
   import flash.net.sendToURL;
   
   var flashVars = this.root.loaderInfo.parameters;
   
   transitionButton.addEventListener(MouseEvent.MOUSE_OVER, adfoxMouseover);//для события наведения
   transitionButton.addEventListener(MouseEvent.MOUSE_OUT, adfoxMouseout);//для события отведения
   transitionButton.addEventListener(MouseEvent.CLICK, adfoxClick);//для клика
   
   function adfoxMouseover(evt:Event):void
   {
       if(ExternalInterface.available)
       {
           sendToURL( new URLRequest(flashVars.event_1) );
           ExternalInterface.call('ADFOX.BACKOVER.globals.applyBackground' + flashVars.adfoxBannerId);
       }
   }
   
   function adfoxMouseout(evt:Event):void
   {
       if(ExternalInterface.available)
       {
           ExternalInterface.call('ADFOX.BACKOVER.globals.resetBackground' + flashVars.adfoxBannerId);
       }
   }
   
   function adfoxClick(evt:Event):void
   {
       if(ExternalInterface.available)
       {
           //IE driven hack;
           ExternalInterface.call('ADFOX.BACKOVER.globals.resetBackground' + flashVars.adfoxBannerId);
           ExternalInterface.call('window.open', flashVars.link1, flashVars.adfoxTarget);
       }
       else
       {
           navigateToURL(new URLRequest(flashVars.link1), flashVars.adfoxTarget);
       }
   }

Подготовка фонового изображения

Чтобы правильно подготовить фоновое изображение нужно учесть, что у каждого пользователя свое разрешение экрана, из-за чего фоновое изображение на различных экранах отображается по-разному.

Например, ширина сайта составляет 1000 px. Создадим фоновое изображение размером 1800 х1000 px.

На экранах с разным разрешением ширина сайта остается неизменной, а вот фоновое изображение при меньшем разрешении будет равномерно обрезано с левой и правой стороны. Ниже приведем пример этих различий.

Для разрешения 1280 х 768:

Для разрешения 1280 х 900:

Для разрешения 1360 х 768: