СЧЁТЕСЛИМН (COUNTIFS)

Применяет условия к ячейкам в нескольких диапазонах и подсчитывает количество соответствий всем условиям.

Алгоритм работы функции:

  • Первая ячейка Диапазона 1 проверяется на соответствие Условию 1, одновременно с этим первая ячейка Диапазона 2 проверяется на соответствие Условию 2 и т. д.
  • Счетчик увеличивается на 1, если все условия выполняются.
  • Далее по такой же схеме проверяются вторые и далее по счету ячейки заданных диапазонов.
  • Когда проанализированы последние по счету ячейки из диапазонов, функция возвращает итоговое значение счетчика.

Функция чаще всего используется, когда в таблице нужно подсчитать количество строк, содержащих определенные значения в разных столбцах. Диапазоны не обязательно должны располагаться рядом — главное, чтобы они были одного размера.

Пример

Результат

=СЧЁТЕСЛИМН(A1:A10; "фрукты"; B1:B10; ">100")

Вернет количество строк, для которых выполняются одновременно два условия: значения в ячейках диапазона от A1 до A10 совпадают со словом «фрукты» и соответствующие им ячейки в диапазоне от B1 до B10 содержат числа больше 100

=СЧЁТЕСЛИМН('Лист1'!A2:A10; "фрукты"; 'Лист2'!A2:A10; ">100")

Вернет количество пар ячеек, для которых выполняются одновременно два условия: значения в ячейках диапазона от A1 до A10 на Листе1 совпадают со словом «фрукты» и соответствующие им ячейки в диапазоне от A1 до A10 на Листе2 содержат числа больше 100

Синтаксис

СЧЁТЕСЛИМН(диапазон1; критерий1; [диапазон2; критерий2]; ...)

Аргументы

Аргумент

Тип данных

Описание

Диапазон 1*

Ссылка

Диапазон, в котором подсчитывается количество ячеек, соответствующих заданному Критерию 1. То есть этот аргумент задает то, где искать.

Критерий 1*

Строка

Условие, выполнение которого проверяется в Диапазоне 1. То есть этот аргумент задает то, что искать. Формат таких строк описан в разделе Строки-условия.

Диапазон 2; Критерий 2; ...

Следующая пара аргументов Диапазон-Критерий. Можно ввести до 127 таких пар. Все заданные диапазоны должны быть такого же размера, как и Диапазон 1 - Критерий 1.

Функция СЧЁТЕСЛИМН будет выполнять подсчет количества только из тех строк, для которых будут выполняться все заданные в ней условия.

Примеры использования

Формула

Результат

Описание

=СЧЁТЕСЛИМН(A2:A9; "*плед*"; B2:B9; ">1000")

3

Количество строк в таблице A2:B9, в которых значения в столбце A содержат слово «плед», а значение в столбце B больше 1000

=СЧЁТЕСЛИМН(A2:A9; "подушка*"; B2:B9; 800)

1

Количество строк в таблице A2:B9, в которых значения в столбце A начинаются со слова «подушка», а значение в столбце B равно 800

=СЧЁТЕСЛИМН(A2:A9; "плед флисовый"; B2:B9; "<>1000")

2

Количество строк в таблице A2:B9, в которых значения в столбце A совпадают со строкой «плед флисовый», а значение в столбце B не равно 1000

=СЧЁТЕСЛИМН(A2:A9; "<>*полотенце*"; B2:B9; "<"&B7)

2

Количество строк в таблице A2:B9, в которых значения в столбце A не содержат слово «полотенце», а значение в столбце B меньше числа, содержащегося в ячейке B7